feat(nix): add opencode-electron derivation

Author: gigamonster256

flake.nix

@@ -45,6 +45,9 @@
             opencode-desktop = final.callPackage ./nix/desktop.nix {
               inherit opencode;
             };
+            opencode-electron = final.callPackage ./nix/desktop-electron.nix {
+              inherit opencode;
+            };
           };
       };
 
@@ -63,6 +66,9 @@
           opencode-desktop = pkgs.callPackage ./nix/desktop.nix {
             inherit opencode;
           };
+          opencode-electron = pkgs.callPackage ./nix/desktop-electron.nix {
+            inherit opencode;
+          };
           # Updater derivation with fakeHash - build fails and reveals correct hash
           node_modules_updater = node_modules.override {
             hash = pkgs.lib.fakeHash;

nix/desktop-electron.nix

@@ -0,0 +1,90 @@
+{
+  lib,
+  stdenv,
+  bun,
+  nodejs,
+  electron_40,
+  makeWrapper,
+  writableTmpDirAsHomeHook,
+  opencode,
+}:
+let
+  electron = electron_40;
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "opencode-electron";
+  inherit (opencode) version src node_modules;
+
+  nativeBuildInputs = [
+    bun
+    nodejs
+    makeWrapper
+    writableTmpDirAsHomeHook
+  ];
+
+  env = opencode.env // {
+    ELECTRON_SKIP_BINARY_DOWNLOAD = "1";
+  };
+
+  # https://github.com/electron/electron/issues/31121
+  # mac builds use a .app bundle which doesnt have this issue
+  postPatch = lib.optionalString stdenv.isLinux ''
+    BASE_PATH=packages/desktop-electron
+    FILES=(src/main/windows.ts)
+    for file in "''${FILES[@]}"; do
+      substituteInPlace $BASE_PATH/$file \
+        --replace-fail "process.resourcesPath" "'$out/opt/opencode-electron/resources'"
+    done
+  '';
+
+  preBuild = ''
+    cp -r "${electron.dist}" $HOME/.electron-dist
+    chmod -R u+w $HOME/.electron-dist
+
+    cp -R ${finalAttrs.node_modules}/. .
+    patchShebangs node_modules
+    patchShebangs packages/*/node_modules
+  '';
+
+  buildPhase = ''
+    runHook preBuild
+
+    cd packages/desktop-electron
+
+    bun run build
+    npx electron-builder --dir \
+      --config electron-builder.config.ts \
+      --config.mac.identity=null \
+      --config.electronDist="$HOME/.electron-dist"
+
+    runHook postBuild
+  '';
+
+  installPhase =
+    ''
+      runHook preInstall
+    ''
+    + lib.optionalString stdenv.hostPlatform.isDarwin ''
+      mkdir -p $out/Applications
+      mv dist/mac*/*.app $out/Applications
+      makeWrapper "$out/Applications/OpenCode.app/Contents/MacOS/OpenCode" $out/bin/opencode-electron
+    ''
+    + lib.optionalString stdenv.hostPlatform.isLinux ''
+      mkdir -p $out/opt/opencode-electron
+      cp -r dist/linux*-unpacked/{resources,LICENSE*} $out/opt/opencode-electron
+      makeWrapper ${lib.getExe electron} $out/bin/opencode-electron \
+        --inherit-argv0 \
+        --set ELECTRON_FORCE_IS_PACKAGED 1 \
+        --add-flags $out/opt/opencode-electron/resources/app.asar \
+        --add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations --enable-wayland-ime=true}}"
+    ''
+    + ''
+      runHook postInstall
+    '';
+
+  meta = {
+    description = "OpenCode Electron Desktop App";
+    mainProgram = "opencode-electron";
+    inherit (opencode.meta) homepage license platforms;
+  };
+})

nix/hashes.json

@@ -1,6 +1,6 @@
 {
   "nodeModules": {
-    "x86_64-linux": "sha256-OPbZUo/fQv2Xsf+NEZV08GLBMN/DXovhRvn2JkesFtY=",
+    "x86_64-linux": "sha256-60KBy/mySuIKbBD5aCS4ZAQqnwZ4PjLMAqZH7gpKCFY=",
     "aarch64-linux": "sha256-WK7xlVLuirKDN5LaqjBn7qpv5bYVtYHZw0qRNKX4xXg=",
     "aarch64-darwin": "sha256-BAoAdeLQ+lXDD7Klxoxij683OVVug8KXEMRUqIQAjc8=",
     "x86_64-darwin": "sha256-ZOBwNR2gZgc5f+y3VIBBT4qZpeZfg7Of6AaGDOfqsG8="

nix/node_modules.nix

@@ -55,7 +55,7 @@ stdenvNoCC.mkDerivation {
       --filter './packages/opencode' \
       --filter './packages/desktop' \
       --filter './packages/app' \
-      --filter './packages/shared' \
+      --filter './packages/desktop-electron' \
       --frozen-lockfile \
       --ignore-scripts \
       --no-progress

nix/opencode.nix

@@ -88,6 +88,7 @@ stdenvNoCC.mkDerivation (finalAttrs: {
 
   passthru = {
     jsonschema = "${placeholder "out"}/share/opencode/schema.json";
+    env = finalAttrs.env;
   };
 
   meta = {