CMake minimum v3.15 for GPU builds.

Author: olupton

CMake/OpenAccHelper.cmake

@@ -14,15 +14,38 @@ if(CORENRN_ENABLE_GPU)
   if(CORENRN_ENABLE_CUDA_UNIFIED_MEMORY)
     add_compile_definitions(CORENEURON_UNIFIED_MEMORY)
   endif()
-  # This is a lazy way of getting the major/minor versions separately without parsing
-  # ${CMAKE_CUDA_COMPILER_VERSION}
-  find_package(CUDAToolkit 9.0 REQUIRED)
-  # Be a bit paranoid
-  if(NOT ${CMAKE_CUDA_COMPILER_VERSION} STREQUAL ${CUDAToolkit_VERSION})
-    message(
-      FATAL_ERROR
-        "CUDA compiler (${CMAKE_CUDA_COMPILER_VERSION}) and toolkit (${CUDAToolkit_VERSION}) versions are not the same!"
-    )
+  if(${CMAKE_VERSION} VERSION_LESS 3.17)
+    # Hopefully we can drop this soon. Parse ${CMAKE_CUDA_COMPILER_VERSION} into a shorter X.Y
+    # version without any patch version.
+    if(NOT ${CMAKE_CUDA_COMPILER_ID} STREQUAL "NVIDIA")
+      message(FATAL_ERROR "Unsupported CUDA compiler ${CMAKE_CUDA_COMPILER_ID}")
+    endif()
+    # Parse CMAKE_CUDA_COMPILER_VERSION=x.y.z into CUDA_VERSION=x.y
+    string(FIND ${CMAKE_CUDA_COMPILER_VERSION} . first_dot)
+    math(EXPR first_dot_plus_one "${first_dot}+1")
+    string(SUBSTRING ${CMAKE_CUDA_COMPILER_VERSION} ${first_dot_plus_one} -1 minor_and_later)
+    string(FIND ${minor_and_later} . second_dot_relative)
+    if(${first_dot} EQUAL -1 OR ${second_dot_relative} EQUAL -1)
+      message(
+        FATAL_ERROR
+          "Failed to parse a CUDA_VERSION from CMAKE_CUDA_COMPILER_VERSION=${CMAKE_CUDA_COMPILER_VERSION}"
+      )
+    endif()
+    math(EXPR second_dot_plus_one "${first_dot}+${second_dot_relative}+1")
+    string(SUBSTRING ${CMAKE_CUDA_COMPILER_VERSION} 0 ${second_dot_plus_one}
+                     CORENRN_CUDA_VERSION_SHORT)
+  else()
+    # This is a lazy way of getting the major/minor versions separately without parsing
+    # ${CMAKE_CUDA_COMPILER_VERSION}
+    find_package(CUDAToolkit 9.0 REQUIRED)
+    # Be a bit paranoid
+    if(NOT ${CMAKE_CUDA_COMPILER_VERSION} STREQUAL ${CUDAToolkit_VERSION})
+      message(
+        FATAL_ERROR
+          "CUDA compiler (${CMAKE_CUDA_COMPILER_VERSION}) and toolkit (${CUDAToolkit_VERSION}) versions are not the same!"
+      )
+    endif()
+    set(CORENRN_CUDA_VERSION_SHORT "${CUDAToolkit_VERSION_MAJOR}.${CUDAToolkit_VERSION_MINOR}")
   endif()
   # -acc enables OpenACC support, -cuda links CUDA libraries and (very importantly!) seems to be
   # required to make the NVHPC compiler do the device code linking. Otherwise the explicit CUDA
@@ -32,8 +55,7 @@ if(CORENRN_ENABLE_GPU)
   # due to e.g. __CUDACC__ being defined. See https://github.com/BlueBrain/CoreNeuron/issues/607 for
   # more information about this. -gpu=cudaX.Y ensures that OpenACC code is compiled with the same
   # CUDA version as is used for the explicit CUDA code.
-  set(NVHPC_ACC_COMP_FLAGS
-      "-acc -gpu=cuda${CUDAToolkit_VERSION_MAJOR}.${CUDAToolkit_VERSION_MINOR}")
+  set(NVHPC_ACC_COMP_FLAGS "-acc -gpu=cuda${CORENRN_CUDA_VERSION_SHORT}")
   set(NVHPC_ACC_LINK_FLAGS "-cuda")
   # Make sure that OpenACC code is generated for the same compute capabilities as the explicit CUDA
   # code. Otherwise there may be confusing linker errors. We cannot rely on nvcc and nvc++ using the

CMakeLists.txt

@@ -111,11 +111,17 @@ if(${CMAKE_CXX_COMPILER_ID} STREQUAL "PGI" OR ${CMAKE_CXX_COMPILER_ID} STREQUAL
 else()
   set(CORENRN_HAVE_NVHPC_COMPILER OFF)
 endif()
+
 if(CORENRN_ENABLE_GPU)
-  # find_package(CUDAToolkit), for example
-  if(${CMAKE_VERSION} VERSION_LESS 3.17)
-    message(FATAL_ERROR "GPU support requires at least CMake v3.17!")
+  # Older CMake versions have not been tested for GPU/CUDA/OpenACC support after
+  # https://github.com/BlueBrain/CoreNeuron/pull/609.
+  # https://cmake.org/cmake/help/latest/release/3.14.html#properties suggests there would be
+  # problems because of expressions like set_target_properties(lfp_test_bin PROPERTIES
+  # CUDA_RESOLVE_DEVICE_SYMBOLS OFF)
+  if(${CMAKE_VERSION} VERSION_LESS 3.15)
+    message(FATAL_ERROR "GPU support requires at least CMake v3.15!")
   endif()
+
   # Fail hard and early if we don't have the PGI/NVHPC compiler.
   if(NOT CORENRN_HAVE_NVHPC_COMPILER)
     message(
@@ -124,16 +130,44 @@ if(CORENRN_ENABLE_GPU)
         " Use NVIDIA HPC SDK with -DCMAKE_C_COMPILER=nvc -DCMAKE_CUDA_COMPILER=nvcc -DCMAKE_CXX_COMPILER=nvc++"
     )
   endif()
+
   # Set some sensible default CUDA architectures.
   if(NOT DEFINED CMAKE_CUDA_ARCHITECTURES)
     set(CMAKE_CUDA_ARCHITECTURES 60 70)
     message(STATUS "Setting default CUDA architectures to ${CMAKE_CUDA_ARCHITECTURES}")
   endif()
+
   # Enable CUDA language support.
   enable_language(CUDA)
-  # nvc++ -cuda implicitly links dynamically to libcudart.so. Setting this makes sure that CMake
-  # does not add -lcudart_static and trigger errors due to mixed dynamic/static linkage.
-  set(CMAKE_CUDA_RUNTIME_LIBRARY Shared)
+
+  # Prefer shared libcudart.so
+  if(${CMAKE_VERSION} VERSION_LESS 3.17)
+    # Ugly workaround from https://gitlab.kitware.com/cmake/cmake/-/issues/17559, remove when
+    # possible
+    if(CMAKE_CUDA_HOST_IMPLICIT_LINK_LIBRARIES)
+      list(REMOVE_ITEM CMAKE_CUDA_HOST_IMPLICIT_LINK_LIBRARIES "cudart_static")
+      list(REMOVE_ITEM CMAKE_CUDA_HOST_IMPLICIT_LINK_LIBRARIES "cudadevrt")
+      list(APPEND CMAKE_CUDA_HOST_IMPLICIT_LINK_LIBRARIES "cudart")
+    endif()
+    if(CMAKE_CUDA_IMPLICIT_LINK_LIBRARIES)
+      list(REMOVE_ITEM CMAKE_CUDA_IMPLICIT_LINK_LIBRARIES "cudart_static")
+      list(REMOVE_ITEM CMAKE_CUDA_IMPLICIT_LINK_LIBRARIES "cudadevrt")
+      list(APPEND CMAKE_CUDA_IMPLICIT_LINK_LIBRARIES "cudart")
+    endif()
+  else()
+    # nvc++ -cuda implicitly links dynamically to libcudart.so. Setting this makes sure that CMake
+    # does not add -lcudart_static and trigger errors due to mixed dynamic/static linkage.
+    set(CMAKE_CUDA_RUNTIME_LIBRARY Shared)
+  endif()
+
+  # Patch CUDA_ARCHITECTURES support into older CMake versions
+  if(${CMAKE_VERSION} VERSION_LESS 3.18)
+    foreach(cuda_arch ${CMAKE_CUDA_ARCHITECTURES})
+      string(
+        APPEND CMAKE_CUDA_FLAGS
+        "--generate-code=arch=compute_${cuda_arch},code=[compute_${cuda_arch},sm_${cuda_arch}]")
+    endforeach()
+  endif()
 endif()
 
 # =============================================================================