sqlite-android/sqlite-android-inspection/build.gradle at 6a3d0531823a3283a583daa7ad29f715aad35559 · requery/sqlite-android · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
plugins {
    id "com.android.library"
    id "com.google.protobuf"
    id "com.vanniktech.maven.publish" version "0.34.0"
}

android {
    buildToolsVersion = "36.1.0"
    compileSdk {
        version = release(36)
    }
    namespace "androidx.sqlite.inspection"
    defaultConfig {
        minSdkVersion 26
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        consumerProguardFiles "consumer-rules.pro"
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_17
        targetCompatibility JavaVersion.VERSION_17
    }
    lint {
        abortOnError false
    }
}

protobuf {
    protoc {
        artifact = "com.google.protobuf:protoc:3.25.3"
    }
    generateProtoTasks {
        all().each { task ->
            task.builtins {
                java {
                    option "lite"
                }
            }
        }
    }
}

dependencies {
    def inspVersion = findProperty("androidx.inspection.version") ?: "1.0.0-SNAPSHOT"
    debugApi("androidx.inspection:inspection:${inspVersion}")
    releaseCompileOnly("androidx.inspection:inspection:${inspVersion}")

    compileOnly("androidx.annotation:annotation:1.8.1")
    api("org.jspecify:jspecify:1.0.0")
    api("com.google.protobuf:protobuf-javalite:3.25.3")
    api(project(":sqlite-android"))

    androidTestImplementation("androidx.test:runner:1.7.0")
    androidTestImplementation("androidx.test.ext:junit:1.3.0")
}

mavenPublishing {
    publishToMavenCentral(/* automaticRelease */ true)
    signAllPublications()
}