Fix NoneType exception for interface dependencies. (#3563)

Before this change any dependency with `CcInfo` which did not contain
static or dynamic libraries (e.g. an interface library which has it's
own fields for storing the underlying files) would result in the
following error:
```
ERROR: /Users/user/Code/rules_rust/test/unit/cc_info/BUILD.bazel:4:19: in rust_shared_library rule //test/unit/cc_info:rust_dylib_with_interface_lib_dep:
Traceback (most recent call last):
	File "/Users/user/Code/rules_rust/rust/private/rust.bzl", line 126, column 32, in _rust_shared_library_impl
		return _rust_library_common(ctx, "cdylib")
	File "/Users/user/Code/rules_rust/rust/private/rust.bzl", line 190, column 32, in _rust_library_common
		return rustc_compile_action(
	File "/Users/user/Code/rules_rust/rust/private/rustc.bzl", line 1541, column 41, in rustc_compile_action
		dynamic_libraries = ctx.runfiles(files = [
Error in runfiles: at index 0 of files, got element of type NoneType, want File
```

This pull request fixes this exception.

Author: UebelAndre

rust/private/rustc.bzl

@@ -1552,7 +1552,7 @@ def rustc_compile_action(
             if CcInfo in dep
             for linker_input in dep[CcInfo].linking_context.linker_inputs.to_list()
             for library_to_link in linker_input.libraries
-            if _is_dylib(library_to_link)
+            if _is_dylib(library_to_link) and library_to_link.dynamic_library
         ])
         transitive_runfiles.append(dynamic_libraries)
     runfiles = runfiles.merge_all(transitive_runfiles)
@@ -1688,6 +1688,14 @@ def _get_std_and_alloc_info(ctx, toolchain, crate_info):
     return toolchain.libstd_and_allocator_ccinfo
 
 def _is_dylib(dep):
+    """Determine if the dependency represents a dynamic library.
+
+    Args:
+        dep (LibraryToLink): The `LibraryToLink` component of a target (e.g. from `CcInfo`)
+
+    Returns:
+        bool: True if the dependency should be thought of as a dynamic library.
+    """
     return not bool(dep.static_library or dep.pic_static_library)
 
 def _collect_nonstatic_linker_inputs(cc_info):

test/unit/cc_info/cc_info_test.bzl

@@ -1,7 +1,7 @@
 """Unittests for rust rules."""
 
 load("@bazel_skylib//lib:unittest.bzl", "analysistest", "asserts")
-load("@rules_cc//cc:defs.bzl", "cc_library")
+load("@rules_cc//cc:defs.bzl", "cc_import", "cc_library")
 load("@rules_cc//cc/common:cc_info.bzl", "CcInfo")
 load("//rust:defs.bzl", "rust_binary", "rust_common", "rust_library", "rust_proc_macro", "rust_shared_library", "rust_static_library")
 
@@ -115,6 +115,68 @@ proc_macro_does_not_provide_cc_info_test = analysistest.make(_proc_macro_does_no
 
 crate_group_info_provides_cc_info_test = analysistest.make(_crate_group_info_provides_cc_info_test_impl)
 
+def _is_cc_interface_library_test_impl(ctx):
+    env = analysistest.begin(ctx)
+    tut = analysistest.target_under_test(env)
+
+    cc_info = tut[CcInfo]
+
+    linker_inputs = cc_info.linking_context.linker_inputs.to_list()
+    asserts.true(
+        env,
+        len(linker_inputs) > 0,
+        "No linker inputs provided by {}".format(tut.label),
+    )
+
+    for linker_input in linker_inputs:
+        asserts.true(
+            env,
+            len(linker_input.libraries) > 0,
+            "No linker input libraries provided by {}".format(tut.label),
+        )
+
+        for library_to_link in linker_input.libraries:
+            asserts.true(
+                env,
+                library_to_link.dynamic_library == None,
+                "dynamic_library unexpectedly provided by {}".format(tut.label),
+            )
+            asserts.true(
+                env,
+                library_to_link.static_library == None,
+                "static_library unexpectedly provided by {}".format(tut.label),
+            )
+            asserts.true(
+                env,
+                library_to_link.pic_static_library == None,
+                "pic_static_library unexpectedly provided by {}".format(tut.label),
+            )
+            asserts.true(
+                env,
+                library_to_link.interface_library != None,
+                "No interface libraries provided by {}".format(tut.label),
+            )
+    return analysistest.end(env)
+
+is_cc_interface_library_test = analysistest.make(_is_cc_interface_library_test_impl)
+
+def _build_test(ctx):
+    env = analysistest.begin(ctx)
+    tut = analysistest.target_under_test(env)
+    if rust_common.crate_info in tut:
+        crate_info = tut[rust_common.crate_info]
+    else:
+        crate_info = tut[rust_common.test_crate_info].crate
+    asserts.true(
+        env,
+        bool(crate_info.output),
+        "No output created by {}".format(tut.label),
+    )
+
+    return analysistest.end(env)
+
+build_test = analysistest.make(_build_test)
+
 def _rust_cc_injection_impl(ctx):
     dep_variant_info = rust_common.dep_variant_info(
         cc_info = ctx.attr.cc_dep[CcInfo],
@@ -136,6 +198,22 @@ rust_cc_injection = rule(
     implementation = _rust_cc_injection_impl,
 )
 
+def _rust_output_extractor_impl(ctx):
+    dep = ctx.attr.dep
+    crate_info = dep[rust_common.test_crate_info].crate
+    output = crate_info.output
+
+    return [DefaultInfo(
+        files = depset([output]),
+    )]
+
+rust_output_extractor = rule(
+    implementation = _rust_output_extractor_impl,
+    attrs = {
+        "dep": attr.label(),
+    },
+)
+
 def _cc_info_test():
     rust_library(
         name = "rlib",
@@ -185,13 +263,41 @@ def _cc_info_test():
         cc_dep = ":cc_lib",
     )
 
+    rust_output_extractor(
+        name = "rust_output_extractor",
+        dep = select({
+            "@platforms//os:windows": ":staticlib",
+            "//conditions:default": ":cdylib",
+        }),
+    )
+
+    cc_import(
+        name = "cc_import",
+        interface_library = ":rust_output_extractor",
+        system_provided = True,
+    )
+
     rust_library(
         name = "rust_lib_with_cc_lib_injected",
         srcs = ["foo.rs"],
         deps = [":cc_lib_injected"],
         edition = "2018",
     )
 
+    rust_library(
+        name = "rust_lib_with_interface_lib_dep",
+        srcs = ["foo.rs"],
+        deps = [":cc_import"],
+        edition = "2018",
+    )
+
+    rust_shared_library(
+        name = "rust_dylib_with_interface_lib_dep",
+        srcs = ["foo.rs"],
+        deps = [":cc_import"],
+        edition = "2018",
+    )
+
     rlib_provides_cc_info_test(
         name = "rlib_provides_cc_info_test",
         target_under_test = ":rlib",
@@ -220,6 +326,18 @@ def _cc_info_test():
         name = "crate_group_info_provides_cc_info_test",
         target_under_test = ":rust_lib_with_cc_lib_injected",
     )
+    is_cc_interface_library_test(
+        name = "is_cc_interface_library_test",
+        target_under_test = ":cc_import",
+    )
+    build_test(
+        name = "rust_lib_with_interface_lib_dep_test",
+        target_under_test = ":rust_lib_with_interface_lib_dep",
+    )
+    build_test(
+        name = "rust_dylib_with_interface_lib_dep_test",
+        target_under_test = ":rust_dylib_with_interface_lib_dep",
+    )
 
 def cc_info_test_suite(name):
     """Entry-point macro called from the BUILD file.
@@ -239,5 +357,8 @@ def cc_info_test_suite(name):
             ":proc_macro_does_not_provide_cc_info_test",
             ":bin_does_not_provide_cc_info_test",
             ":crate_group_info_provides_cc_info_test",
+            ":is_cc_interface_library_test",
+            ":rust_lib_with_interface_lib_dep_test",
+            ":rust_dylib_with_interface_lib_dep_test",
         ],
     )