Add basilisp.csv namespace (#1327)

Author: chrisrink10

CHANGELOG.md

@@ -5,6 +5,9 @@ The format is based on [Keep a Changelog](https://keepachangelog.com/en/1.0.0/),
 and this project adheres to [Semantic Versioning](https://semver.org/spec/v2.0.0.html).
 
 ## [Unreleased]
+### Added
+ * Added `basilisp.csv` namespace (#753)
+
 ### Changed
  * Add `test` and `tests` directories to `PYTHONPATH` automatically during `basilisp test` CLI invocations (#1069)
 

docs/api/csv.rst

@@ -0,0 +1,10 @@
+basilisp.csv
+============
+
+.. toctree::
+   :maxdepth: 2
+   :caption: Contents:
+
+.. autonamespace:: basilisp.csv
+   :members:
+   :undoc-members:

src/basilisp/csv.lpy

@@ -0,0 +1,59 @@
+(ns basilisp.csv
+  "Wrapper functions for :external:py:mod:`csv` which reads and writes CSVs."
+  (:require
+   [basilisp.io :as bio])
+  (:import
+   csv))
+
+(defn read-csv
+  "Returns a lazy sequence of vectors corresponding to the rows of a CSV file.
+
+  If ``input`` is a string, it will be treated as the contents of a CSV. Otherwise,
+  it will be treated as a :external:py:class:`io.TextIOBase`.
+
+  The reader function supports the following keyword arguments:
+
+   :keyword ``:separator``: the character used as the separator for a fields in a row
+       default is \",\"
+   :keyword ``:quote``: the quote character used on quoted fields; default is ``true``"
+  [input & {:keys [separator quote] :or {separator "," quote "\""}}]
+  (let [f       (if (string? input)
+                  (io/StringIO input)
+                  input)
+        reader  (csv/reader f ** :delimiter separator :quotechar quote)
+        do-read (fn read-csv*
+                  []
+                  (when-some [row (python/next reader nil)]
+                    (cons (vec row) (lazy-seq (read-csv*)))))]
+    (lazy-seq (do-read))))
+
+(defn rows->maps
+  "Returns a lazy sequence mapping over a sequence of CSV data (as vectors)
+  converting them to maps.
+
+  The first row will be used as the headers. The ``:key-fn`` keyword argument
+  names a function which will be used to map over the keys."
+  [rows & {:keys [key-fn] :or {key-fn keyword}}]
+  (let [header (mapv key-fn (first rows))]
+    (map #(zipmap header %) (rest rows))))
+
+(defn write-csv
+  "Write a sequence of rows in CSV format to ``writer``, which should be an
+  :external:py:class:`io.TextIOBase`.
+
+  The writing function supports the following keyword arguments:
+
+   :keyword ``:separator``: the character used as the separator for a fields in a row
+       default is \",\"
+   :keyword ``:quote``: the quote character used on quoted fields; default is ``true``
+   :keyword ``:newline``: the newline character to use between rows (``:lf`` or
+       ``:cr+lf``)"
+  [writer data & {:keys [separator quote newline] :or {separator "," quote "\"" newline :lf}}]
+  (let [nl (cond
+             (= newline :lf)    "\n"
+             (= newline :cr+lf) "\r\n"
+             :else              (throw
+                                 (ex-info "newline must be one of: :lf or :cr+lf"
+                                          {:newline newline})))
+        w  (csv/writer writer ** :delimiter separator :quotechar quote :lineterminator nl)]
+    (.writerows w (map #(mapv str %) data))))

tests/basilisp/test_csv.lpy

@@ -0,0 +1,56 @@
+(ns tests.basilisp.test-csv
+  (:require
+   [basilisp.csv :as csv]
+   [basilisp.test :refer [deftest is are testing]])
+  (:import io))
+
+(def test-csv-content
+  "id,name,country
+1,John,United Kingdom
+2,Hanns,Germany
+3,Jose,Spain")
+
+(def test-csv-headers
+  ["id" "name" "country"])
+
+(def test-csv-rows
+  '(["1" "John" "United Kingdom"]
+    ["2" "Hanns" "Germany"]
+    ["3" "Jose" "Spain"]))
+
+(deftest read-csv-test
+  (testing "string"
+    (is (= '() (csv/read-csv "")))
+    (is (= '() (csv/rows->maps (csv/read-csv "id,name"))))
+    (is (= (concat [test-csv-headers] test-csv-rows)
+           (csv/read-csv test-csv-content)))
+    (is (= (map zipmap (repeat [:id :name :country]) test-csv-rows)
+           (csv/rows->maps (csv/read-csv test-csv-content)))))
+
+  (testing "file-like object"
+    (with-open [f (io/StringIO)]
+      (is (= '() (csv/read-csv f))))
+    (with-open [f (io/StringIO "id,name")]
+      (is (= '() (csv/rows->maps (csv/read-csv f)))))
+    (with-open [f (io/StringIO test-csv-content)]
+      (is (= (concat [test-csv-headers] test-csv-rows)
+             (csv/read-csv f))))
+    (with-open [f (io/StringIO test-csv-content)]
+      (is (= (map zipmap (repeat [:id :name :country]) test-csv-rows)
+             (csv/rows->maps (csv/read-csv f)))))))
+
+(deftest write-csv-test
+  (is (thrown? basilisp.lang.exception/ExceptionInfo
+               (csv/write-csv (io/StringIO) [] :newline :wrong-nl)))
+
+  (with-open [f (io/StringIO)]
+    (csv/write-csv f [])
+    (is (= "" (.getvalue f))))
+
+  (with-open [f (io/StringIO)]
+    (csv/write-csv f [test-csv-headers])
+    (is (= "id,name,country\n" (.getvalue f))))
+
+  (with-open [f (io/StringIO)]
+    (csv/write-csv f (concat [test-csv-headers] test-csv-rows))
+    (is (= (str test-csv-content "\n") (.getvalue f)))))