phpantom_lsp/flake.nix at main · AJenbo/phpantom_lsp · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
{
  description = "Flake for phphantom-lsp (local development)";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
        };

        manifest = (pkgs.lib.importTOML ./Cargo.toml).package;
        stubsLock = pkgs.lib.importTOML ./stubs.lock;
        repoParts = pkgs.lib.splitString "/" stubsLock.repo;

        owner = builtins.elemAt repoParts 0;
        repo = builtins.elemAt repoParts 1;

        stubsTarball = pkgs.fetchurl {
          url = "https://github.com/${owner}/${repo}/archive/${stubsLock.commit}.tar.gz";

          # convert hex → SRI
          hash = builtins.convertHash {
            hash = stubsLock.sha256;
            hashAlgo = "sha256";
            toHashFormat = "sri";
          };
        };

        stubsSrc = pkgs.runCommand "phpstorm-stubs" { } ''
          mkdir -p $out
          tar -xzf ${stubsTarball} --strip-components=1 -C $out
        '';
      in
      {
        packages.default = self.packages.${system}.phpantom-lsp;
        packages.phpantom-lsp = pkgs.rustPlatform.buildRustPackage {
          pname = manifest.name;
          cargoLock.lockFile = ./Cargo.lock;
          version = manifest.version;

          # Use current directory as the source
          src = pkgs.lib.cleanSource ./.;

          postPatch = ''
            mkdir -p stubs/jetbrains
            cp -a ${stubsSrc} stubs/jetbrains/phpstorm-stubs
            chmod u+wx stubs/jetbrains/phpstorm-stubs
            echo "${stubsLock.commit}" > stubs/jetbrains/phpstorm-stubs/.commit
          '';

          checkFlags = [
            "--test"
            "completion_inheritance"
          ];

          postInstall = ''
            mv $out/bin/phpantom_lsp $out/bin/phpantom-lsp
            ln -s $out/bin/phpantom-lsp $out/bin/phpantom_lsp
          '';
        };
      }
    );
}